blob: 24973df17448aeb4be54a59e88e54c6a9794676d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
/* -*- Mode: IDL; tab-width: 8; indent-tabs-mode: t; c-basic-offset: 8 -*- */
/*
* Interface to allow components to switch between on-line and off-line mode.
*
* Authors:
* Ettore Perazzoli <ettore@ximian.com>
*
* Copyright (C) 2001 Ximian, Inc.
*/
#include <Bonobo.h>
module GNOME {
module Evolution {
struct Connection {
string hostName;
string type;
};
typedef sequence<Connection> ConnectionList;
interface OfflineProgressListener {
/* Update the shell about the progress of going off-line. The
operation is considered completed when the ConnectionList is empty. */
void updateProgress (in ConnectionList current_active_connections);
};
interface SyncFolderProgressListener {
/* Report that syncing is progressed @percent %. */
void updateProgress (in float percent);
/* Report an error. */
void reportFailure (in string message);
};
interface Offline : Bonobo::Unknown {
exception notPrepared {};
exception notSyncing {};
/* Whether the component is currently off-line. */
attribute boolean isOffline;
/* Ask the component to prepare to go into off-line mode. The
component must return a list of the current active connections.
After this call, the shell is expected to either invoke
`::goOffline()' (actually complete the operation and go off-line) or
`::goOnline()' (operation cancelled). */
void prepareForOffline (out ConnectionList active_connection_list);
/* Request the component to sync the specified folder. This has to
happen after ::prepareForOffline. */
void syncFolder (in Folder folder,
in SyncFolderProgressListener listener)
raises (notPrepared);
/* Request the component to stop syncing the specified folder. This
has to happen after ::syncFolder. */
void cancelSyncFolder (in string evolution_uri,
in string physical_uri)
raises (notSyncing);
/* Ask the component to go into off-line mode. This always comes after
a `::prepareForOffline'. */
void goOffline (in OfflineProgressListener listener)
raises (notPrepared);
/* Tell the component to go into on-line mode. */
void goOnline ();
};
};
};
|
